ComObjActive() [AHK_L 53+]

检索已使用 OLE(对象连接与嵌入) 注册的运行对象.

ComObject := ComObjActive(CLSID)

创建一个表示要作为参数或返回值传递的类型化值的对象.

ParamObj := ComObject(VarType, Value , Flags)

不建议: 不推荐使用以下方法, 后续版本中可能被替换或不再支持.

在调用 COM(组件对象模型) 对象的方法时创建一个可用于替代可选参数默认值的对象. [v1.1.12+]: 这种函数已废弃使用. 作为代替, 使用两个连续的逗号, 如 Obj.Method(1,,3)

ParamObj := ComObjMissing()

装包或拆包位于可用对象的原始 IDispatch 指针, 并自动调用 AddRef(增加引用).

ComObject := ComObjEnwrap(DispPtr)
DispPtr := ComObjUnwrap(ComObject)

要写更多面向未来的代码, 请改用以下代码:

ComObject := ComObject(9, DispPtr, 1), ObjAddRef(DispPtr)
DispPtr := ComObjValue(ComObject), ObjAddRef(DispPtr)

参数

CLSID

要检索的 COM 对象的 CLSID 或可读 Prog ID.

ComObject

可以使用对象语法的 COM 对象.

VarType

表示值类型的整数. 类型列表见 ComObjType().

Value

要包装的值. 当前仅支持整数值和指针值.

Flags

影响此函数和包装器对象行为的标志, 请参阅后面.

DispPtr

原始的 IDispatch 指针.

Flags

 0 

默认行为. AddRef(增加引用) 自动调用 IUnknown 和 IDispatch 的指针, 所以调用者应该适当使用 ObjRelease() 释放指针的副本.

未来版本中可能改变此默认行为, 因此建议当包装接口指针时总是设置 标志 为 1, 需要时再调用 ObjAddRef().
 1  取得 IUnknown, IDispatch 或 SAFEARRAY(安全数组) 指针的所有权. 不调用 AddRef. 如果包装器对象包含 SAFEARRAY(VT_BYREF 除外), 那么当包装器对象被释放时会自动调用 SafeArrayDestroy.

ByRef [v1.1.17+]

如果包装器对象的 变量类型 包含 VT_BYREF(0x4000) 标签, 可用空的方括号对 [] 来读写引用的值.

当创建一个引用, 值 须为变量的内存地址, 或足够存储指定类型的值的缓存. 例如, 下面的代码可以用来创建一个 VBScript 函数可以写入的变量:

VarSetCapacity(var, 24, 0)
vref := ComObject(0x400C, &var)  ; 0x400C 是 VT_BYREF 与 VT_VARIANT 组合而得.

vref[] := "in value"
sc.Run("Example", vref)  ; sc 应像下面例子一样进行初始化.
MsgBox % vref[]

一般说明

当前版本中, 任何以"ComObj"开头的函数调用, 如果不匹配目录列表中的其他 COM 函数, 则实际调用 ComObjActive 函数. 如, ComObjEnwrap(DispPtr) 及 ComObjActive(DispPtr) 均等效于 ComObject(DispPtr)(隐式地, 变量类型 为 9). 此行为可能于后续版本不再可用, 故建议仅使用本页所展示的 ComObject() 及 ComObjActive().

如果 ComObjActive 不能检索活动的对象, 则可能会抛出异常, 退出脚本或返回空字符串, 具体取决于当前的 ComObjError() 设置和其他因素.

当使用此函数包装或检索 IDispatch 或 IUnknown 接口指针时, 默认的行为会增加 COM 对象的引用计数. 因此, 当不使用时, 须手动释放接口指针. 当用于封装的对象被释放时, 他所包含的引用被自动释放.

已知限制: 每次包装 COM 对象时, 都会创建新的包装器对象. 如 if (obj1 == obj2), array[obj1] := value 这样的比较和赋值运算, 会把两个包装器对象视为独立的, 即使它们包含相同的 COM 对象.

ComObjCreate(), ComObjGet(), ComObjConnect(), ComObjError(), ComObjFlags(), ObjAddRef() / ObjRelease(), ComObjQuery(), GetActiveObject (MSDN)

示例

ComObjUnwrap(COM 对象拆包): 参见ComObjConnect().

#1

; 条件 - ScriptControl 需 32 位版本的 AutoHotkey.
code =
(
Sub Example(Var)
    MsgBox Var
    Var = "out value!"
End Sub
)
sc := ComObjCreate("ScriptControl"), sc.Language := "VBScript", sc.AddCode(code)


; 示例: 传递 VARIANT ByRef 至 COM 函数.
var := ComVar()
var[] := "in value"
sc.Run("Example", var.ref)
MsgBox % var[]


; ComVar: 创建可用于按引用(ByRef) 传值的对象.
;   ComVar[] 返回值.
;   ComVar[] := Val 设置值.
;   ComVar.ref 返回用于 COM 函数的按引用传值的对象.
ComVar(Type=0xC)
{
    static base := { __Get: "ComVarGet", __Set: "ComVarSet", __Delete: "ComVarDel" } ; 有关 base, 请参阅自定义对象.
    ; 创建含 1 个 VARIANT 类型变量的数组.  此方法可以让内部代码处理
    ; 在 VARIANT 和 AutoHotkey 内部类型之间的所有转换.
    arr := ComObjArray(Type, 1)
    ;锁定数组并检索到 VARIANT 的指针.
    DllCall("oleaut32\SafeArrayAccessData", "ptr", ComObjValue(arr), "ptr*", arr_data)
    ;保存数组及可用于按引用传递 VARIANT 值的对象.
    return { ref: ComObject(0x4000|Type, arr_data), _: arr, base: base }
}

ComVarGet(cv, p*) { ; 当脚本访问未知字段时调用.
    if p.MaxIndex() = "" ; 没有名称/参数, 如, cv[]
        return cv._[0]
}

ComVarSet(cv, v, p*) { ; 当脚本设置未知字段时调用.
    if p.MaxIndex() = "" ; 没有名称/参数, 如, cv[]:=v
        return cv._[0] := v
}

ComVarDel(cv) { ; 当对象被释放时调用.
    ; 必须进行这样的处理才能释放内部数组.
    DllCall("oleaut32\SafeArrayUnaccessData", "ptr", ComObjValue(cv._))
}